Since 2022 Sort Finance

Turtle Breakout

How this strategy trades, what it scored, and the measurements the score was read from: every symbol and timeframe, on real and resampled history.

How It Trades

  1. Track the previous 20-bar high, the previous 10-bar low, and the 20-bar average range.
  2. Buy when the close breaks above the 20-bar high: the classic Turtle trend entry.
  3. Exit on whichever comes first: the close falling below the 10-bar low (the trend has rolled over), or a safety stop 2 average ranges below the entry price (the trade went wrong quickly).

Example Strategy

Pine Script

Paste it into TradingView’s Pine Editor to run these rules on any chart.

//@version=6
// Turtle Breakout — sort.finance. Fills at the signal bar's close, 0.02% fee a side,
// whole account per trade, as the backtest. History and indicator warm-up
// differ from the site's, so expect close to the same trades, not identical.
strategy("Turtle Breakout", overlay=true,
     initial_capital=100, default_qty_type=strategy.percent_of_equity,
     default_qty_value=100, commission_type=strategy.commission.percent,
     commission_value=0.02, process_orders_on_close=true, pyramiding=0)

// The bar the current position opened on, and the bar the last one closed on.
var int entryBar = na
var int exitBar = -1

// ── Signals ──────────────────────────────────────────────────────────────
entryHigh = ta.highest(close, 20)[1]
exitLow = ta.lowest(close, 10)[1]
rangeAverage = ta.sma(ta.tr(true), 20)
var float stopLevel = na
enterNow = close > entryHigh
// The stop is fixed on the bar the position opens.
if strategy.position_size == 0 and bar_index > exitBar and enterNow
    stopLevel := close - 2.0 * rangeAverage
exitNow = close <= stopLevel or close < exitLow

// ── Orders ───────────────────────────────────────────────────────────────
// Open on the first bar the entry holds while flat; close on the first
// later bar the exit holds; never reopen on the bar a position closed.
inTrade = strategy.position_size != 0
if inTrade and bar_index > entryBar and exitNow
    strategy.close("Long")
    exitBar := bar_index
else if not inTrade and bar_index > exitBar and enterNow
    strategy.entry("Long", strategy.long)
    entryBar := bar_index

// ── Drawing ──────────────────────────────────────────────────────────────
plot(entryHigh, "Entry Channel", color=#4d8dff)
plot(exitLow, "Exit Channel", color=#e0a03a)
plot(strategy.position_size != 0 ? stopLevel : na, "Stop", color=#b54a48, style=plot.style_linebr)