Since 2022 Sort Finance

Stochastic Oscillator

How this strategy trades, what it scored, and the measurements the score was read from: every symbol and timeframe, on real and resampled history.

How It Trades

  1. Compute %K (where the close sits inside the 14-bar high-low range, from 0 at the bottom to 100 at the top) and %D, its 3-bar average.
  2. Buy when %K crosses above %D while still below 20: price is pinned near the bottom of its recent range but has just started turning up, which is Lane's oversold reversal.
  3. Sell when %K reaches 80, the top fifth of the range.

Example Strategy

Pine Script

Paste it into TradingView’s Pine Editor to run these rules on any chart.

//@version=6
// Stochastic Oscillator — sort.finance. Fills at the signal bar's close, 0.02% fee a side,
// whole account per trade, as the backtest. History and indicator warm-up
// differ from the site's, so expect close to the same trades, not identical.
strategy("Stochastic Oscillator", overlay=false,
     initial_capital=100, default_qty_type=strategy.percent_of_equity,
     default_qty_value=100, commission_type=strategy.commission.percent,
     commission_value=0.02, process_orders_on_close=true, pyramiding=0)

// The bar the current position opened on, and the bar the last one closed on.
var int entryBar = na
var int exitBar = -1

// ── Signals ──────────────────────────────────────────────────────────────
k = ta.sma(ta.stoch(close, high, low, 14), 3)
d = ta.sma(k, 3)
enterNow = k[1] <= d[1] and k > d and k < 20
exitNow = k > 80

// ── Orders ───────────────────────────────────────────────────────────────
// Open on the first bar the entry holds while flat; close on the first
// later bar the exit holds; never reopen on the bar a position closed.
inTrade = strategy.position_size != 0
if inTrade and bar_index > entryBar and exitNow
    strategy.close("Long")
    exitBar := bar_index
else if not inTrade and bar_index > exitBar and enterNow
    strategy.entry("Long", strategy.long)
    entryBar := bar_index

// ── Drawing ──────────────────────────────────────────────────────────────
plot(k, "%K", color=#4d8dff)
plot(d, "%D", color=#e0a03a)
hline(20, "Oversold 20", color=color.new(#8a92a0, 40), linestyle=hline.style_dashed)
hline(80, "Overbought 80", color=color.new(#8a92a0, 40), linestyle=hline.style_dashed)